You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 

90 lines
2.1 KiB

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PLOCALES="ar be bg ca cmn cs da de el en_GB es es_AR es_MX et fi fr gl hu id_ID it ja ko lt lv ml_IN ms nl pl pt_BR pt_PT ru si sk sl sq sr sr_RS sv ta tr uk zh_CN zh_TW"
MY_P="${P/_/-}"
if [[ ${PV} == *9999 ]]; then
inherit autotools git-r3 plocale
EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
else
SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
fi
inherit xdg
DESCRIPTION="Lightweight and versatile audio player"
HOMEPAGE="https://audacious-media-player.org/"
SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
LICENSE="BSD-2"
SLOT="0"
IUSE="nls"
BDEPEND="
virtual/pkgconfig
nls? ( dev-util/intltool )
"
DEPEND="
>=dev-libs/dbus-glib-0.60
>=dev-libs/glib-2.28
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
>=x11-libs/cairo-1.2.6
>=x11-libs/pango-1.8.0
virtual/freedesktop-icon-theme
"
RDEPEND="${DEPEND}"
PDEPEND="~media-plugins/audacious-plugins-${PV}"
S="${WORKDIR}/${MY_P}"
src_unpack() {
default
[[ ${PV} == *9999 ]] && git-r3_src_unpack
}
src_prepare() {
default
if ! use nls; then
sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
fi
rm_locale() {
rm -vf "po/${1}.po" || die
sed -i s/${1}.po// po/Makefile || die
}
plocale_find_changes po "" ".po"
plocale_for_each_disabled_locale rm_locale
[[ ${PV} == *9999 ]] && eautoreconf
}
src_configure() {
# D-Bus is a mandatory dependency, remote control,
# session management and some plugins depend on this.
# Building without D-Bus is *unsupported* and a USE-flag
# will not be added due to the bug reports that will result.
# Bugs #197894, #199069, #207330, #208606
local myeconfargs=(
--disable-valgrind
--disable-gtk
--enable-dbus
--enable-qt
$(use_enable nls)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
# Gentoo_ice skin installation; bug #109772
insinto /usr/share/audacious/Skins/gentoo_ice
doins -r "${WORKDIR}"/gentoo_ice/.
docinto gentoo_ice
dodoc "${WORKDIR}"/README
}